Обращение к процедурам и функциям

 Синтаксис

Вызов процедур (в исполнительной части в качестве оператора):

<Имя процедуры>[(<Список фактических параметров>)]

 

Вызов функций (используются в выражениях):

<Имя функции>[(<Список фактических параметров>)]

 

В списке фактических параметров перечисляются через запятую значения передаваемых в процедуру или функцию параметров. Количество и тип фактических параметров должны соответствовать описанным в заголовке формальным параметрам. При вызове процедуры или функции формальные параметры принимают значения переданных туда фактических параметров.

 Пример

PrintNumber(10);

Writeln(Mul(4,7));

PrintNumber(Mul(2,3)+8);

 

 

Лекция 5

Процедуры и функции. Процедурные типы. Тип указатель

5.1. Модификаторы VAR и CONST в описании формальных параметров

Если не указывать никаких модификаторов, то при передаче фактических параметров в процедуру или функцию создается временная копия значения фактического параметра, которая используется в процедуре или функции и удаляется после выхода. При использовании модификатора VAR в качестве формального параметра передается переменная (точнее ссылка на переменную). Значение переменной, переданной по ссылке, можно изменить внутри процедуры или функции. При этом изменится и значение переменной, указанной в качестве параметра.

 Пример

PROCEDURE VectorSum(x1,y1,x2,y2:Real;VAR x,y:Real);

BEGIN

x:=x1+x2;

y:=y1+y2;

END;

VAR x,y:Real;

∙ ∙ ∙

VectorSum(3,7,5,10,x,y);

 

 Результат выполнения

x=8, y=17

 

Таким образом, можно использовать этот способ передачи параметров, например для возврата процедурой или функцией, если это необходимо, сразу нескольких значений. Заметьте, что в этом случае значения может возвращать и процедура. Существуют случаи, когда передавать переменные по ссылке, а не по значению обязательно. Часто этот модификатор применяется для переменных составных типов (например, строк и массивов).

Модификатор CONST применяется в основном для переменных составных типов в случае, когда значение параметра внутри процедуры или функции изменять не требуется. В этом случае не создается временная копия значений параметров, а, как и при использовании модификатора VAR, переменные передаются по ссылке, что сокращает время на создание копии больших составных переменных. Передавать значения по ссылке допускается, так как можно быть уверенным, что, как и при обычной передаче параметров, значение переменных не изменится. Если попытаться изменить значение параметра, описанного с модификатором CONST, будет выдано сообщение об ошибке.

 

Локальность и область действия

Все описания, находящиеся в описательной части процедуры или функции, являются локальными для нее и недоступны в основной программе или в других процедурах и функциях. Переменные, описанные в основной программе, являются глобальными и доступны всем процедурам и функциям. Локальные переменные, в отличие от глобальных, не существуют до вызова процедуры или функции, в которой они описаны. При входе в процедуру или функцию для локальных переменных динамически выделяется память, а при выходе эта память освобождается.

 Пример

VAR A,B,C:Integer;

PROCEDURE Test(A:STRING);

VAR

B:Char;

BEGIN

B:='B';

Writeln(A,B,C);

END;

BEGIN
A:=1;

B:=2;

C:=3;

Test('Str');

Writeln(A,B,C);

END.

 

 Результат выполнения

StrB3

 

Необходимо заметить, что значения типизированных констант, где бы они ни были описаны, являются глобальными, т.е. если в процедуре или функции описана типизированная константа, то для нее уже выделена память и ей присвоено конкретное значение. Если в процедуре или функции поменять это значение, то при следующем вызове измененное значение типизированной константы сохранится.

 Пример

CONST

n:Integer=25;

 

PROCEDURE Test;

CONST

n:Integer=1;

BEGIN

Writeln('Local n=',n);

Inc(n);

END;

 

BEGIN

Test;

Test;

Writeln('Global n=',n);

END.

 

 Результат выполнения

Local n=1

Local n=2

Global n=25

 

 

Процедурные типы

 Синтаксис

Тип "процедура":

PROCEDURE [(Список формальных параметров>)]

 

Тип "функция":

FUNCTION [(Формальне параметры>)]:<Тип результата>

 

Рассмотрим использование процедурных типов на примерах. Предположим, что необходимо приближенно (численно) проинтегрировать некоторую функцию f (x) на отрезке [ a, b ] путем разбиения отрезка на n частей и приближенной замены интеграла суммой площадей прямоугольников, как показано на следующем рисунке.

Напишем функцию для численного интегрирования, к примеру, функции .

 Функция Integr

FUNCTION Integr(a,b:Real;n:Integer):Real;

VAR

i:Integer;

dx,x:Real;

BEGIN

dx:=(b-a)/n;

Result:=0;

FOR i:=0 TO n-1 DO

BEGIN

x:=dx*I+dx/2;

Result:=Result+(Sin(x)+x/2)*dx;

END;

END;

 

Предположим теперь, что в программе необходимо интегрировать несколько функций, причем для вычисления значений некоторых из них вполне может понадобиться писать целую отдельную программу. Что делать в этом случае? Написать несколько почти одинаковых функций для каждого случая? Необходимо заметить, что в реальной задаче могут использоваться и значительно более сложные вычисления, для которых может понадобиться написание достаточно объемной программы. Придется несколько раз продублировать эту программу, меняя в ней лишь небольшой участок. В таких случаях можно использовать процедурные типы. Перепишем вышеприведенную функцию Integr с использованием процедурных типов.

 Функция Integr

TYPE

Func=FUNCTION (x:Real):Real;

FUNCTION Integr(f:Func;a,b:Real;n:Integer):Real;

VAR

i:Integer;

dx:Real;

BEGIN

dx:=(b-a)/n;

Result:=0;

FOR i:=0 TO n-1 DO

Result:=Result+f(dx*I+dx/2)*dx;

END;

 

Теперь в качестве параметров передаются не только отрезок интегрирования и количество участков, но и функция, которую необходимо интегрировать. Таким образом, теперь можно интегрировать любую функцию без необходимости многократно дублировать код.

 Пример использования функции Integr

FUNCTION f1(x:Real):Real;

BEGIN

f1:=Sin(x)+x/2;

END;

∙ ∙ ∙

Writeln(Integr(f1,1,5,1000));

 

 

Тип указатель

 Синтаксис

^<Тип>

 

Переменная типа указатель содержит адрес некоторой переменной описанного типа. Рассмотрим на примере тип указатель, а также оператор взятия адреса @ и оператор разыменования указателя ^.

 Пример

VAR

A:Word;

B:Integer;

P:^Integer;

∙ ∙ ∙

A:=10;

B:=1000;

P:=@B;

P^:=A; { B принимает значение 10 }

P:=@A; { Ошибка, если включена опция "Типизированный оператор @"
(по умолчанию эта опция выключена) }

 

После выполнения первых трех операторов присваивания переменные примут значения, приведенные на следующем рисунке (расположение переменных в памяти взято для примера).

Нулевой указатель

Записывается NIL и означает, что переменная типа указатель не указывает ни на что. Возвращаясь к процедурным типам, скажем, что значение NIL можно присваивать и переменным такого типа (так как, по сути, они являются указателями и содержат адреса соответствующих процедур и функций). В данном случае это будет означать, что переменная не указывает ни на какую процедуру или функцию. Чтобы определить адрес процедуры или функции, на которую указывает переменная процедурного типа (например, для сравнения с NIL), нужно использовать оператор взятия адреса @.

 Пример (продолжение примера из параграфа 5.3)

PROCEDURE Test(f,G:Func); { G – первообразная f }

BEGIN

Writeln('Приближенное значение интеграла: ',
Integr(f,1,5,1000));

IF @G<>NIL THEN

Writeln('Точное значение интеграла: ',
G(5)-G(1));

END;

 

FUNCTION G1(x:Real):Real;

BEGIN G1:=Sqr(x)/4-Cos(x) END;

{ Первообразная функции }

 

FUNCTION f2(x:Real):Real;

BEGIN f2:=Sin(x)/x END;

{ Интеграл – не берущийся }

∙ ∙ ∙

Test(f1,G1); { Напечатаются приближенное
и точное значения }

Test(f2,NIL); { Напечатается только
приближенное значение }

 

 

Лекция 6